Im currently working on a zelda game, but there seems to be a problem with it.....You fight a frog,but quest just closes down.Is it to do with my varibles?

define game <The Legend Of Zelda>
	asl-version <350>
	gametype singleplayer
	start <Your House1>
	game author <Francis Robert Stokes>
	game version <1.0>
	game info <Similar sort of game to OOT.Have fun with it!>
	default fontname <Copperplate Gothic Light>
	default fontsize <12>
	startscript {
		playmidi <zelda1.MID; loop>
		msg <|jc|cl|s45---------|n-------------------|n----------------------------|n---------------------------------------|nThe Legend Of Zelda:|n------------------------------------------------------|nThe Call Of The Woods|n-------------------------------------------------------------------|n|s00|cbSome of the characters in this game were made by Nintendo and are not the creation of Francis Stokes.|w|c>
		choose <PlayedBefore>
	}
	afterturn inc <TC; 1>
	type <sword>
	type <sheild>
	define variable <Rupees>
		type numeric
		value <0>
		display <Ruppes   !>
	end define
	define variable <TC>
		type numeric
		value <0>
		display <Turns   !>
	end define
	define variable <Health>
		type numeric
		value <100>
		display <Health ! / 100>
		onchange {
			if ( %Health% <= 0 ) then playerlose
			if ( %Health% >= 100 ) then set numeric <Health; 100>
		}
	end define
	define variable <Sw1>
		type numeric
		value <5>
	end define
	define variable <Sh1>
		type numeric
		value <5>
	end define
	define variable <Lv1monster>
		type numeric
		value <$rand(1;9)$>
	end define
	define variable <Lv1monsterH>
		type numeric
		value <20>
	end define
end define

define synonyms
	burn; light up; set light to = light
end define

define room <Your House1>
	alias <Your Tree House>
	look <You wake from a restless sleep with lines of sweat dripping down your face.You get up and put on your clothes.Your small sword stands gracefully in the corner,with your sheild.You feel an unconsious call from the woods and the pounding of a terrified heart.It is time to leave the village and answer the call of the woods.>
	north <D1>
	script playmidi <>

	define object <HyruleWarriorSword>
		alias <Hyrulian Warriors Sword>
		look <A longsword with a winged handle made with solid blue silver.>
		take <You grip the handle and lift the sword.You swing it a few times then put it away.>
		gain if got <HyruleWarriorSword> and got <HyruleWarriorSheild> then create exit west <Your House1; OutsideYourHouse> else msg <Before you leave,you should at least be equipped with a sheild as well as a sword.>
		examine <This type of sword is used widely by the Hyrulian Army.>
		prefix <a>
		displaytype <Warriors Sword>
		article <it>
		gender <it>
		drop nowhere <>
	end define

	define object <HyruleWarriorSheild>
		alias <Hyrulian Warriors Sheild>
		look <There are patterns of the |cy|iTriforce|xi|cb on this sheild.>
		take <You put the sheild on your back.>
		gain if got <HyruleWarriorSword> and got <HyruleWarriorSheild> then create exit west <Your House1; OutsideYourHouse> else msg <Before you leave,you should at least be equipped with a sword as well as a sheild.>
		examine <This is a sheild used by the Hyrulian Army.>
		prefix <a>
		displaytype <Warrior Sheild>
		article <it>
		gender <it>
		properties <def=5>
	end define

end define

define room <OutsideYourHouse>
	alias <Outside Your House>
	look <You stand on the wooden board-walk outside your door.You can hear the call of the woods getting louder,and you can almost tell that is a female voice.In front of you is a ladder leading down to the village.>
	indescription <You slowly walk:>
	down <BottomOfTheLadder>
end define

define room <BottomOfTheLadder>
	alias <Path To The Village>
	prefix <the>
	look <You look above you to the sky and see the moon.It looks almost disturbed,like somthing is bothering it.You look to the west and see outlines of trees.These are the woods.The screams seem to go quiet.>
	indescription <You climb down the ladder to:>
	west <Woods>
	up msg <You are about to climb back up the ladder,when another loud scream sounds.You must head for the woods.>
end define

define room <Woods>
	prefix <The>
	look <You heart races as the sound of an almost silent scream echos among the trees.You find yourself dreamng of the bed you just left,back in your tree house.Up ahead,you see two trees forming an archway,in which the village temple of the Trifrorce is located.>
	indescription <You slowly step into:>
	north <Temple To The Triforce1>
end define

define room <Temple To The Triforce1>
	alias <Temple To The Triforce>
	look <You stand staring at the alter of the temple,watching a man in a black cloak draw a sword to  a young women of the village.You suddenly feel a surge of power run through you and you fiind yourself taking out your sword.you begin to run at the man,and as he sees you,he disappears with the girl.You stop in your tracks as you can still hear her screams.You run up to the alter....there is a broken jewel lying on the ground,split into two halves.>
	indescription <You walk into the:>
	script playmidi <zelda2tri.MID; loop>

	define object <BrokenJewel>
		alias <Broken Jewel>
		look <It is a considerably large broken ruby,with a gold centre,shaped like the triforce.>
		take <You kneel down,study the stone for a while,then pick it up.>
		gain {
			msg <|jc.....|nYou turn around to see an old man standing on the path.|n"Hello,|cgLink.|cbMy name is Gabreille.That stone you have just found is the Triforce Temple Ruby.It is one of the four stones that keeps the sacred realm closed.I know that you think you are just a normal villager,but there are thing that you do not know,things that were kept from you.|wYou are a Hylan,but not just any Hylan.You are a decendant of the |crHero of time|cb!And this is why you must know of some important matters....there is an evil around that is trying to rescue |crThe man of the desert|cb,Ganandorf!You have to stop to stop this evil from breaking the other three temple stones.I can tell you no more,but i must get you out of here quickly,as there are many monsters roaming these woods...|w|jl>
			playmidi <>
			goto <ForVillage1>
		}
		examine <It is a considerably large broken ruby,with a gold centre,shaped like the triforce.>
	end define

end define

define room <ForVillage1>
	alias <Village>
	prefix <the>
	look <You look around to see that the old man has gone.|nThe land has woken up,and there are many birds chirping and many villagers are now awake and roaming around.You see houses,like yours,built into trees and built on the ground.|nAlot of your old friends are out....it would be nice to talk to some of them!>
	indescription <You walk into:>
	north {
		msg <You walk up the path.>
		show <Villager3>
	}

	define object <Villager1>
		alias <Villager>
		look <He is wearing a green tunic.>
		speak msg <"Hi Link!I haven't seen you around for a long time.....Hey!Do you remember how we used to pretend we were hylan warriors?!We used to |clUse our sword on whatever...|cb">
		examine <He is one of your old friends.>
		prefix <a male>
		displaytype <male villager>
		article <him>
		gender <he>
	end define

	define object <Villager2>
		alias <Villager>
		look <She is wearing a green tunic.>
		speak msg <"Hi Link!The other day i couldn't find my key and i remembered that i left it under a pot.I had to |clLIFT THE POT|cl to find it.|cb">
		examine <She is one of your old friends.>
		prefix <a female>
		displaytype <female villager>
		article <her>
		gender <she>
	end define

	define object <Villager3>
		alias <Villager>
		look <He is wearing a green tunic.>
		speak {
			msg <"Hi Link!What have you been doing with yourself?....Oh yeah!He was looking you...said that it was important...">
			show <Cloaked Villager>
		}
		examine <He is one of your old friends.>
		prefix <a male>
		displaytype <male villager>
		article <him>
		gender <he>
		hidden
	end define

	define object <Cloaked Villager>
		alias <Cloaked Villager>
		look <This person wears a dark robe.>
		speak {
			msg <"Link.....The time hath come to seal your fate.This quest can only be undertaken by the Hero of Time...and that is you,Link.You must come with me to the Elders House...>
			wait <Press any key....>
			goto <Forvillage2(EH)>
		}
		examine <This person is unknown to you.>
		prefix <a>
		displaytype <Cloaked Villager>
		article <This person>
		gender <This person>
		hidden
	end define

end define

define room <Forvillage2(EH)>
	alias <Elders House>
	prefix <The>
	indescription <You and the cloaked stranger enter:>
end define

define room <D1>
	alias <Dungeon -Of- Water>
	look <You walk into a dark caved in Dungeon.You can hear screeching of bats and other things that you would rather not think about!|nYou look around you.....There are three torches against the far wall, two lit, one in the middle un-lit.There is also a door with bars dropped over it....You wonder how it opens......>
	indescription <You find yourself in the:>
	script playmidi <; loop>
	command <Light stick> if got <Stick> then {
		msg <The stick starts to burn...you could light something with this!>
		lose <Stick>
		hide <Stick>
		show <Lit stick1>
		give <Lit stick1>
	}
	else msg <You do not appear to have a stick.>

	define object <Lit Torch1>
		alias <Lit Torch>
		look <The torch appears to have been handcrafted out of....silver?>
		take {
			msg <You burn yourself!>
			dec <Health; 5>
		}
		examine <The flame burns brightly.>
		prefix <a>
		suffix <against the wall>
		article <it>
		gender <it>
	end define

	define object <Unlit Torch2>
		alias <Un-lit Torch>
		look <The torch appears to have been handcrafted out of....silver?>
		take {
			msg <You burn yourself!>
			dec <Health; 5>
		}
		examine <There was a fire burning in this torch not so long ago...>
		prefix <an>
		suffix <against the wall>
		article <it>
		gender <it>
	end define

	define object <Lit Torch2>
		alias <Lit Torch>
		look <The torch appears to have been handcrafted out of....silver?>
		take {
			msg <You burn yourself!>
			dec <Health; 5>
		}
		examine <The flame burns brightly.>
		prefix <a>
		suffix <against the wall>
		article <it>
		gender <it>
	end define

	define object <Stick>
		alias <Stick>
		look <It is a stick from an dead tree.>
		take <You pick up the stick.>
		examine <It is a stick from an dead tree.>
		prefix <a>
		suffix <lying on the floor>
	end define

	define object <Lit stick1>
		alias <Stick (lit)>
		look <The stick now burns letting off a huge amount of smoke!>
		take
		examine <The stick now burns letting off a huge amount of smoke!>
		article <it>
		gender <it>
		hidden
		use on <Unlit Torch2> {
			msg <You hold the burning stick to the torch and it instantly starts to burn.You hear a sort of slamming sound and turn to see the bars have gone from the door.Your stick burns to a crisp as you let the ashes fall to the ground.>
			lose <Lit stick1>
			hide <Lit stick1>
			hide <Unlit Torch2>
			reveal <Lit Torch3>
			create exit south <D1; D2>
		}
	end define

	define object <Lit Torch3>
		alias <Lit Torch>
		look <The torch appears to have been handcrafted out of....silver?>
		take {
			msg <You burn yourself!>
			dec <Health; 5>
		}
		examine <The flame burns brightly.>
		prefix <a>
		suffix <against the wall>
		article <it>
		gender <it>
		invisible
	end define

end define

define room <D2>
	alias <Dark Room>
	prefix <a>
	look <You wander into a dark room.There is a a giant frog in the middle of the room!>
	script show <Giant Frog>

	define object <Giant Frog>
		look {
			msg <It spits its tounge out and hits you!>
			dec <Health; 5>
		}
		prefix <a>
		use <HyruleWarriorSword> if ( %Sw1% > %Lv1monster% ) then {
			msg <You slash the frog!>
			dec <Lv1monsterH; 5>
			if ( %Lv1monsterH% <= 0 ) then hide <Giant Frog> else {
				msg <The frog attempts to hit back!>
				dec <Health; $rand(0;10)$>
			}
		}
		else {
			msg <The frog dodes the attack and trys to hit back!>
			dec <Health; $rand(0;7)$>
		}
		properties <lv1def=3>
	end define

end define

define text <intro>

end define

define text <win>

end define

define text <lose>

end define

define selection <PlayedBefore>
	info <Have you played LOZ:COTW before?|w>
	choice <Yes,i have played before> msg <|c|jl>
	choice <No,i have not played before> msg <|c|jc.....Long ago.......|w|nThere was a power formed by the gods.This power was named the Triforce and set to rest in the sacred realm....|w|cThe Triforce stayed at rest in the sacred realm,untill an evil |crMan of the desert|cb began an attempt to steal the trifroce.But just at this time,the |clHero of time|cb defeated him in a battle that formed legends.The |clhero of time|cb locked the |crevil man of the desert|cb away in the sacred realm and the Triforce could once again rest in peace....|w|c|jl>
end define

thanks to anyone that can help.

I move the player straight to D2 and give him the sword.... I then kill the frog.
Quest doesn't close for me.

Are messages displayed when you use the sword on the frog,like :-

you hit the frog

?

i still dont get these messages,all i get are errors.

grrrrrrrrrrrrrrrrrrrrrrrrrrrrr

Completely random somewhat out of topic thought:

Make the default message for taking something say: "You grin wildly and levitate (item) above your head while humming a small tune!".

No error's... Just "you hit the frog" over until I kill it.

Maybe it's just a bug, some people may get it and some don't.
if it is your game make sure Debug is on.

Im on my main computer,but i made the game on my laptop,and it didnt work at all.I tried it on here and it works just fine.

I can't see why it won't work on my laptop.

I'd love to see a zelda game in quest, being a huge zelda fan myself, but if you can't test it easily, then you've got urself a problem.